印表機快速安裝批次檔 - Android 台灣中文網

@echo off
::本批次檔用於印表機快速安裝,可省去大量人工操作
::執行時請勿右鍵以系統管理員身分執行,安裝時會出現系統警告,確認後即可繼續
::安裝在需要權限的地方時,會出現輸入帳號密碼的視窗,此時再輸入即可
::【設定印表機名稱和ip位置】
::自動模式停用=0 啟用=1 『預設啟用=1』
::自動模式需先在下列先設定好印表機IP和顯示名稱
set automatic=1
if "%automatic%"=="1" goto auto
if "%automatic%"=="0" goto Manual
::【自動模式】
:auto
::請預先輸入印表機IP
set print_ip=192.168.10.72
::請預先輸入印表機顯示名稱,可中文
set print_name=HP Universal Printing PCL 6 (v7.3.0)
goto data
::【手動模式】
:Manual
set /p aa=請輸入印表機IP:
set print_ip=%aa%
set /p aaa=請輸入印表機顯示名稱:
set print_name=%aaa%
goto data
:data
::【安裝完成後要執行的功能】
::設成預設『停用=0 啟用=1』
set preset=0
::列印測試頁『停用=0 啟用=1』
set test=0
::印表機佇列檢視『停用=0 啟用=1』
set view=0
::印表機內容『停用=0 啟用=1』
set pcontent=0
::【連接埠進階設定】
::連接埠如有特殊需求可由這裡修改
::SNMP停用=0 啟用=1 『預設停用=0』
set snmp_in=0
::連接埠類型 raw=0 lpr=1 『預設raw=0』
set rl_in=0
::連接埠號碼RAW 『預設9100』
set rl=9100
::佇列名稱LPR 『預設print』
set ln=print
::連接埠名稱『預設』
set pro=%print_ip%
::【※※※※※ 驅動程式INF檔位置及印表機名稱 ※※※※※】
::64位元INF驅動路徑及INF內的對應印表機名稱
set path64=%~dp0upd-pcl6-x64-7.3.0.25919\hpcu310u.inf
set model64=HP Universal Printing PCL 6 (v7.3.0)
::32位元INF驅動路徑及INF內的對應印表機名稱
set path32=%~dp0upd-pcl6-x32-7.3.0.25919\hpcu310c.inf
set model32=HP Universal Printing PCL 6 (v7.3.0)
:: ★★★★★ 以下是程式執行部分,勿隨意修改 ★★★★★
set pip=%print_ip%
set p_name="%print_name%"
if "%pbackup%"=="1" goto bk
if "%PROCESSOR_ARCHITECTURE%" == "AMD64" goto x64
if "%PROCESSOR_ARCHITECTURE%" == "x86" goto x86
:x64
set driver="%path64%"
set name="%model64%"
set pbits=SysWOW64
goto print_install
:x86
set driver="%path32%"
set name="%model32%"
set pbits=system32
goto print_install
:print_install
echo.
echo.
echo. 正在安裝印表機 %print_name% ip %print_ip%
echo.
echo.
echo. 驅動程式安裝中不同電腦大約需要1~5分鐘
echo.
echo.
echo. 如出現系統提示請選擇繼續、是或確認
echo.
echo.
echo. 安裝完成後本視窗會自動關閉
echo.
echo.
echo.
@echo off
if "%rl_in%"=="0" set rawlpr=raw
if "%rl_in%"=="1" set rawlpr=lpr
if "%rl_in%"=="0" set rln=-n %rl% -2e
if "%rl_in%"=="1" set rln=-q %ln% -2d
if "%snmp_in%"=="0" set snmp=-md
if "%snmp_in%"=="1" set snmp=-me
%windir%\%pbits%\cscript.exe %windir%\%pbits%\Printing_Admin_Scripts\zh-TW\prnport.vbs -t -r %pro% -h %pip% -o %rawlpr% %rln% %snmp%
rundll32 printui.dll,PrintUIEntry /if /b %p_name% /f %driver% /r %pro% /m %name%
goto print_set
:print_set
if "%preset%"=="1" rundll32 printui.dll,PrintUIEntry /y /n %p_name%
if "%test%"=="1" rundll32 printui.dll,PrintUIEntry /k /n %p_name%
if "%view%"=="1" rundll32 printui.dll,PrintUIEntry /o /n %p_name%
if "%pcontent%"=="1" rundll32 printui.dll,PrintUIEntry /p /n %p_name%
goto exit
exit

複製代碼